Jenkinsfile

/*
 * Copyright (C) 2020 Das Land Schleswig-Holstein vertreten durch den
 * Ministerpräsidenten des Landes Schleswig-Holstein
 * Staatskanzlei
 * Abteilung Digitalisierung und zentrales IT-Management der Landesregierung
 *
 * Lizenziert unter der EUPL, Version 1.2 oder - sobald
 * diese von der Europäischen Kommission genehmigt wurden -
 * Folgeversionen der EUPL ("Lizenz");
 * Sie dürfen dieses Werk ausschließlich gemäß
 * dieser Lizenz nutzen.
 * Eine Kopie der Lizenz finden Sie hier:
 *
 * https://joinup.ec.europa.eu/collection/eupl/eupl-text-eupl-12
 *
 * Sofern nicht durch anwendbare Rechtsvorschriften
 * gefordert oder in schriftlicher Form vereinbart, wird
 * die unter der Lizenz verbreitete Software "so wie sie
 * ist", OHNE JEGLICHE GEWÄHRLEISTUNG ODER BEDINGUNGEN -
 * ausdrücklich oder stillschweigend - verbreitet.
 * Die sprachspezifischen Genehmigungen und Beschränkungen
 * unter der Lizenz sind dem Lizenztext zu entnehmen.
 */
pipeline {
    agent {
       node {
           label 'ozgcloud-jenkins-build-agent-jdk21'
        }
    }

    environment {
        JENKINS_URL = "https://jenkins.infra.ozg-cloud.systems/job/codeSH_eingang-manager/job/${env.BRANCH_NAME}/${env.BUILD_NUMBER}/"
        RELEASE_REGEX = /\d+.\d+.\d+/
        SNAPSHOT_REGEX = /\d+.\d+.\d+-SNAPSHOT/
        FAILED_STAGE = ""
        SH_SUCCESS_STATUS_CODE = 0
    }

    options {
        timeout(time: 1, unit: 'HOURS')
        disableConcurrentBuilds()
        buildDiscarder(logRotator(numToKeepStr: '5'))
    }

    stages {
        stage('Check Version') {
            steps {
                script {
                    FAILED_STAGE = env.STAGE_NAME
                    def rootPom = readMavenPom file: 'pom.xml'
                    def rootVersion = rootPom.version
                    def vorgangManagerVersion = rootPom.properties['vorgang-manager.version']

                    def commonVersion = getParentPomVersion('common/pom.xml')
                    def routerVersion = getParentPomVersion('router/pom.xml')
                    def forwarderVersion = getParentPomVersion('forwarder/pom.xml')
                    def formCycleAdapterVersion = getParentPomVersion('formcycle-adapter/pom.xml')
                    def enterpriseAdapterVersion = getParentPomVersion('enterprise-adapter/pom.xml')

                    if(env.BRANCH_NAME == 'release'){
                        if ( !isReleaseVersion([rootVersion, vorgangManagerVersion, commonVersion, routerVersion, forwarderVersion, formCycleAdapterVersion, enterpriseAdapterVersion])) {
                            error("Keine Release Version für Branch ${env.BRANCH_NAME}.")
                        }
                    } else {
                        if ( !isSnapshotVersion([rootVersion, commonVersion, routerVersion, forwarderVersion, formCycleAdapterVersion, enterpriseAdapterVersion])) {
                            error("Keine Snapshot Version für Branch ${env.BRANCH_NAME}.")
                        }
                    }

                    if ( !isSameVersion([commonVersion, routerVersion, forwarderVersion, formCycleAdapterVersion, enterpriseAdapterVersion], rootVersion)) {
                        error("Versionen sind nicht identisch")
                    }
                }
            }
        }
        stage('Set Version') {
          when {
            not {
                anyOf {
                    branch 'main'
                    branch 'release'
                }
            }
          }
          steps {
                script {
                    FAILED_STAGE=env.STAGE_NAME
                    JAR_TAG = getPomVersion('pom.xml').replace("SNAPSHOT", "${env.BRANCH_NAME}-SNAPSHOT")
                }
                configFileProvider([configFile(fileId: 'maven-settings', variable: 'MAVEN_SETTINGS')]) {
                    sh "mvn -s $MAVEN_SETTINGS versions:set -DnewVersion=${JAR_TAG} -DprocessAllModules=true"

                }
          }
        }
        stage('Build Eingang-Adapter') {
            steps {
                script {
                    FAILED_STAGE=env.STAGE_NAME
                }
                configFileProvider([configFile(fileId: 'maven-settings', variable: 'MAVEN_SETTINGS')]) {
                    sh 'mvn --version'
                    sh 'mvn -s $MAVEN_SETTINGS -P ci-build clean install -Dmaven.wagon.http.retryHandler.count=3'

                    script {
                      	try {
	                        if (env.BRANCH_NAME == 'main') {
		                        withSonarQubeEnv('sonarqube-ozg-sh'){
		        					sh 'mvn -s $MAVEN_SETTINGS sonar:sonar'
		                        }
		                    }
		                } catch (Exception e) {
	                        unstable("SonarQube failed")
	                    }
                    }
                }
            }
            post {
                always{
                    junit testResults: '**/target/surefire-reports/*.xml', skipPublishingChecks: true
                }
            }
        }

        stage('Deploy Eingang-Adapter to Nexus'){
            steps {
                script {
                    FAILED_STAGE = env.STAGE_NAME
                }
                configFileProvider([configFile(fileId: 'maven-settings', variable: 'MAVEN_SETTINGS')]) {
                    sh 'mvn -s $MAVEN_SETTINGS -DskipTests deploy'
                    sh "mvn -s $MAVEN_SETTINGS versions:revert"
                }
            }
        }

        stage('Tag and Push Docker image') {
            steps {
                script {
                    FAILED_STAGE=env.STAGE_NAME
                    IMAGE_TAG = buildVersionName()

                    tagAndPushDockerImage('formcycle-adapter', IMAGE_TAG)
                    tagAndPushDockerImage('enterprise-adapter', IMAGE_TAG)
                    tagAndPushDockerImage('forwarder', IMAGE_TAG)

                    if (env.BRANCH_NAME == 'main') {
                        tagAndPushDockerImage('formcycle-adapter', 'snapshot-latest')
                        tagAndPushDockerImage('enterprise-adapter', 'snapshot-latest')
                        tagAndPushDockerImage('forwarder', 'snapshot-latest')
                    }
                    else if (env.BRANCH_NAME == 'release') {
                        tagAndPushDockerImage('formcycle-adapter', 'latest')
                        tagAndPushDockerImage('enterprise-adapter', 'latest')
                        tagAndPushDockerImage('forwarder', 'latest')
                    }
                }
            }
        }

        stage('Test, build and deploy Eingang-Adapter Helm Chart') {
            steps {
                script {
                    FAILED_STAGE=env.STAGE_NAME
                    HELM_CHART_VERSION = buildVersionName()

                    sh "./run_helm_test.sh"

                    dir('src/main/helm') {
                        sh "helm package --version=${HELM_CHART_VERSION} ."

                        deployHelmChart("eingang-adapter", HELM_CHART_VERSION)
                    }
                }
            }
        }

        stage('Trigger Dev rollout') {
            when {
                branch 'main'
            }
            steps {
                script {
                    FAILED_STAGE = env.STAGE_NAME

                    cloneGitopsRepo()

                    setNewDevAdapterVersion()

                    pushNewDevVersion()
                }
            }
        }
        stage('Trigger Test rollout') {
            when {
                branch 'release'
            }

            steps {
                script {
                    FAILED_STAGE = env.STAGE_NAME

                    cloneGitopsRepo()

                    setNewTestAdapterVersion()

                    pushNewTestVersion()
                }
            }
        }

        stage ('Deploy SBOM to DependencyTrack') {
            steps {
                script {
                    IMAGE_TAG = buildVersionName()

                    configFileProvider([configFile(fileId: 'maven-settings', variable: 'MAVEN_SETTINGS')]) {
                        withCredentials([string(credentialsId: 'dependency-track-api-key', variable: 'API_KEY')]) {

                            catchError(buildResult: 'UNSTABLE', stageResult: 'FAILURE') {
                                sh "mvn  --no-transfer-progress -s $MAVEN_SETTINGS io.github.pmckeown:dependency-track-maven-plugin:upload-bom -Ddependency-track.apiKey=$API_KEY -Ddependency-track.projectVersion=${IMAGE_TAG} -Ddependency-track.dependencyTrackBaseUrl=https://dependency-track.ozg-sh.de"
                            }
                        }
                    }
                }
            }
        }

    }
    post {
        failure {
            script {
                if (env.BRANCH_NAME == 'main' || env.BRANCH_NAME == 'release') {
                    sendFailureMessage()
                }
            }
        }
    }
}

Void deployHelmChart(String helmChartName, String helmChartVersion) {
    withCredentials([usernamePassword(credentialsId: 'jenkins-nexus-login', usernameVariable: 'USERNAME', passwordVariable: 'PASSWORD')]){
        if (env.BRANCH_NAME == 'release') {
            result = sh script: '''curl -u $USERNAME:$PASSWORD https://nexus.ozg-sh.de/service/rest/v1/components?repository=ozg-base-apps -F file=@'''+helmChartName+'''-'''+helmChartVersion+'''.tgz''', returnStdout: true
        }
        else {
            result = sh script: '''curl -u $USERNAME:$PASSWORD https://nexus.ozg-sh.de/service/rest/v1/components?repository=ozg-base-apps-snapshot -F file=@'''+helmChartName+'''-'''+helmChartVersion+'''.tgz''', returnStdout: true
        }

        if (result != '') {
            error(result)
        }
    }
}

String validateBranchName(branchName) {
    int maxLength = 30
    if (branchName.length() > maxLength) {
        String originalBranchName = branchName
        branchName = branchName.substring(0, maxLength)
        echo "WARNING: Branch name '${originalBranchName}' exceeded ${maxLength} characters. " +
             "It has been truncated to '${branchName}' for deployment purposes."
    }
    return branchName
}

String buildVersionName() {
    if (env.BRANCH_NAME == 'release') {
        return getPomVersion('pom.xml')
    }
    return "${getPomVersion('pom.xml')}-${validateBranchName(env.BRANCH_NAME)}-${env.BUILD_NUMBER}".replaceAll("_", "-")
}

Void sendFailureMessage() {
    def room = ''
    def data = """{"msgtype":"m.text", \
                    "body":"Eingang-Manager: Build Failed. Stage: ${FAILED_STAGE} Build-ID: ${env.BUILD_NUMBER} Link: ${JENKINS_URL}", \
                    "format": "org.matrix.custom.html", \
                    "formatted_body":"Eingang-Manager: Build Failed. Stage: ${FAILED_STAGE} Build-ID: <a href='${JENKINS_URL}'>${env.BUILD_NUMBER}</a>"}"""

    if (env.BRANCH_NAME == 'main') {
        room = "!GjqhmouBtnDbwUkAjx:matrix.ozg-sh.de"
    }
    else if (env.BRANCH_NAME == 'release') {
        room = "!oWZpUGTFsxkJIYNfYg:matrix.ozg-sh.de"
    }

    sh "curl -XPOST -H 'authorization: Bearer ${getElementAccessToken()}' -d '${data}' https://matrix.ozg-sh.de/_matrix/client/v3/rooms/$room/send/m.room.message"
}

String getElementAccessToken() {
    withCredentials([string(credentialsId: 'element-login-json', variable: 'LOGIN_JSON')]) {
        return readJSON ( text: sh (script: '''curl -XPOST -d \"$LOGIN_JSON\" https://matrix.ozg-sh.de/_matrix/client/v3/login''', returnStdout: true)).access_token
    }
}

Void setNewDevAdapterVersion() {
    setNewFormcycleAdapterVersion('dev')
    setNewEnterpriseAdapterVersion('dev')
    setNewForwarderVersion('dev')
}

Void setNewTestAdapterVersion() {
    setNewFormcycleAdapterVersion('test')
    setNewEnterpriseAdapterVersion('test')
}

Void setNewFormcycleAdapterVersion(String environment) {
    dir("gitops") {
        def envFile = "${environment}/application/values/formcycle-adapter-values.yaml"
        def envVersions = readYaml file: envFile

        envVersions.formcycle_adapter.image.tag = IMAGE_TAG
        envVersions.formcycle_adapter.helm.version = HELM_CHART_VERSION

        writeYaml file: envFile, data: envVersions, overwrite: true
    }
}

Void setNewEnterpriseAdapterVersion(String environment) {
    dir("gitops") {
        def envFile = "${environment}/application/values/enterprise-adapter-values.yaml"
        def envVersions = readYaml file: envFile

        envVersions.enterprise_adapter.image.tag = IMAGE_TAG
        envVersions.enterprise_adapter.helm.version = HELM_CHART_VERSION

        writeYaml file: envFile, data: envVersions, overwrite: true
    }
}

Void setNewForwarderVersion(String environment) {
    dir("gitops") {
        def envFile = "${environment}/application/values/forwarder-values.yaml"
        def envVersions = readYaml file: envFile

        envVersions.forwarder.image.tag = IMAGE_TAG
        envVersions.forwarder.helm.version = HELM_CHART_VERSION

        writeYaml file: envFile, data: envVersions, overwrite: true
    }
}

Void pushNewDevVersion() {
    pushNewGitopsVersion('dev')
}

Void pushNewTestVersion() {
    pushNewGitopsVersion('test')
}

Void pushNewGitopsVersion(String environment) {
    dir('gitops') {
        if (!hasAdapterValuesFileChanged(environment)) {
            return
        }

        withCredentials([usernamePassword(credentialsId: 'jenkins-gitea-access-token', passwordVariable: 'TOKEN', usernameVariable: 'USER')]) {
            sh "git add ${environment}/application/values/*-adapter-values.yaml"

            sh "git commit -m 'jenkins rollout ${environment} eingang-manager version ${IMAGE_TAG}'"
            sh 'git push https://${USER}:${TOKEN}@git.ozg-sh.de/ozgcloud-devops/gitops.git'
        }
    }
}

Boolean hasAdapterValuesFileChanged(String environment) {
    return sh (script: "git status | grep '${environment}/application/values/.*-adapter-values.yaml'", returnStatus: true) == env.SH_SUCCESS_STATUS_CODE as Integer
}

Void configureGit() {
    final email = "jenkins@ozg-sh.de"
    final name = "jenkins"

    dir("gitops") {
        sh "git config user.email '${email}'"
        sh "git config user.name '${name}'"
    }
}

Void cloneGitopsRepo() {
    withCredentials([usernamePassword(credentialsId: 'jenkins-gitea-access-token', passwordVariable: 'TOKEN', usernameVariable: 'USER')]) {
        sh 'git clone https://${USER}:${TOKEN}@git.ozg-sh.de/ozgcloud-devops/gitops.git'
    }

    configureGit()
}

Void tagAndPushDockerImage(String imageName, String newTag){
    withCredentials([usernamePassword(credentialsId: 'jenkins-nexus-login', usernameVariable: 'USER', passwordVariable: 'PASSWORD')]) {
        sh 'docker login docker.ozg-sh.de -u ${USER} -p ${PASSWORD}'

        sh "docker tag docker.ozg-sh.de/${imageName}:build-latest docker.ozg-sh.de/${imageName}:${newTag}"
        sh "docker push docker.ozg-sh.de/${imageName}:${newTag}"
    }
}

String getPomVersion(String pomFile){
    def pom = readMavenPom file: pomFile

    return pom.version
}

String getParentPomVersion(String filePath) {
    def pom = readMavenPom file: filePath
    return pom.parent.version
}

Boolean isReleaseVersion(List versions) {
    return matchRegexVersion(versions, RELEASE_REGEX)
}

Boolean isSnapshotVersion(List versions) {
    return matchRegexVersion(versions, SNAPSHOT_REGEX)
}

Boolean matchRegexVersion(List versions, String regex) {
    for (version in versions) {
        if ( !(version ==~ regex) ) {
            return false
        }
    }

    return true
}

Boolean isSameVersion(List versions, String expectedVersion) {
    for (version in versions) {
        if ( version != expectedVersion ) {
            return false
        }
    }

    return true
}